Reliability and Reliability Engineering (Supplemental2)

This is another supplementary material for the entry Reliability Part1. In another entry I provided a JMP JSL script that demostrates the properties of a Weibull Distribution. In this entry I will provide a JMP JSL script that shows the properties of the Lognormal Distribution.
The Lognormal Distribution Function is characterized by 2 parameters which are the Scale and the Shape. This distribution is usually used to model Faulure Times where aging is the most dominant cause of failure. Here is a JMP JSL script that demonstrates how the Lognormal distribution changes as each of these parameters change.

The JMP JSL Script is shown below

Clear Globals();
Shap = 2;
Scal = 4;


PDF_fx = Expr( Exp( -(Log( x ) - Log( Scal )) ^ 2 / (2 * Shap ^ 2) ) / (Shap * x * Sqrt( 2 * Pi() )) );
   
Log_Window = New Window( "Properties of the LogLogistic Density and Hazard Functions",
 V List Box(
  GraphWindow = Graph(
   FrameSize( 500, 500 ),
   Double Buffer,
   FrameSize( 500, 300 ),
   X Scale( 0, 3 ),
   Y Scale( 0, 1 ),
   Double Buffer,
   A = Scal;
   B = Shap;
   TEXT_MESSAGE = "; Scale parameter A = " || Char( A ) || "; Shape parameter B = " || Char( B );
   NON_EXPO2 = Expr( Caption( TEXT_MESSAGE ) );
   Pen Size( 2 );
   Pen Color( "red" );
   Text Color( "red" );
   Text Size( 12 );
   Text( {1, .7}, "LogNormal Probability Distribution Function" );
   Y Function( PDF_fx, x );
  ),
  H List Box(
   V List Box(
    H List Box( TB1 = Text Box( " Scale Parameter A" ), Text Box( "  " ) ),
    Slider Box(
     0.0001,
     20,
     Scal,
     GraphWindow << reshow;
     Log_Window << reshow;
     A = Scal;
     B = Shap;
     TEXT_MESSAGE = "; Scale parameter A = " || Char( A ) || "; Shape parameter B = " || Char( B );
     NON_EXPO2;
    )
   ),
   V List Box(
    H List Box( TB2 = Text Box( " Shape Parameter B" ), Text Box( "  " ) ),
    Slider Box(
     0.0001,
     10,
     Shap,
     GraphWindow << reshow;
     A = Scal;
     B = Shap;
     TEXT_MESSAGE = "; Scale parameter A = " || Char( A ) || "; Shape parameter B = " || Char( B );
     NON_EXPO2;
    )
   )
  )
 )
);
TB1 << Font color( "BLUE" );
TB1 << set Font size( 10 );
TB2 << Font color( "BLUE" );
TB2 << set Font size( 10 );

Reliability and Reliability Engineering (Supplemental)

This is a supplementary material for the entry Reliability Part1. A bulk of reliability concepts revolves around the discussion of the Weibull Distribution and its associated Hazard Function.
The Weibull Distribution Function is characterized by 3 parameters namely Beta (for the shape), Eta (for the scale), and Gamma (for the location). Here is a JMP JSL script that demonstrates how the Weibull distribution changes as each of these parameters change. The output window is shown below:

The JMP JSL Script is shown below::

Beta_value = 1.5;
Eta_value = 2.0;
Gamma_value = 0;


EXPO = Expr(
 MESSAGEBOX = New Window( "NOTICE:",
  Border Box(
   top( 10 ),
   Left( 10 ),
   Panel Box( "Read:",
    Text Box( "If the value of the shape parameter Beta = 1, the Weibull becomes an Exponential Distribution" )
   )
  )
 );
 Wait( 2 );
 MESSAGEBOX << CLOSE WINDOW;
);

TEXT_MESSAGE = "Shape parameter Beta = " || char(Beta_value) ||"; Scale parameter Eta = "  || char(Eta_value) || "; Location parameter Gamma = " || char(Gamma_value);

NON_EXPO1 = Expr(Caption( "If the value of the shape parameter Beta = 1, the Weibull becomes an Exponential Distribution. " ));
NON_EXPO2 = Expr(Caption(TEXT_MESSAGE));

Weibull_Window = New Window( "Properties of the Weibull Density and Hazard Functions",
 V List Box(
  GraphWindow = Graph(
  FrameSize(500,500), 
  Double Buffer,
   FrameSize( 500, 300 ),
   X Scale( 0, 3 ),
   Y Scale( 0, 4 ),
   Double Buffer,
   Y Function( (Beta_value / x) * (x / eta_value) ^ Beta_value * Exp( -(x / eta_value) ^ Beta_value ), x );  /* density */
   Y Function( (Beta_value / x) * (x / eta_value) ^ Beta_value, x );                /* hazard */
   Pen Size( 2 );
   Pen Color( "red" );
   Text Color ("red");
   Text Size(12);
   text({1,.7},"Weibull Probability Distribution Function",);
   Y Function(
    (Beta_value / Eta_value) * ((x - gamma_value) / eta_value) ^ (Beta_value - 1) *
    Exp( -1 * ((x - gamma_value) / eta_value) ^ Beta_value ),
    x
   );
   Pen Color( "Blue" );
   Text Color ("Blue");
   Text Size(12);
   text({0.8,1.2},"Hazard Function",);
   Y Function( (Beta_value / Eta_value) * ((x - gamma_value) / eta_value) ^ (Beta_value - 1), x );
  ),
  H List Box(
   V List Box(
    H List Box( TB1=Text Box("Shape Parameter Beta"), Text Box("  ") ),
    Slider Box(
     0,
     10,
     Beta_value,
     TEXT_MESSAGE = "Shape parameter Beta = " || char(Beta_value) ||"; Scale parameter Eta = "  || char(Eta_value) || "; Location parameter Gamma = " || char(Gamma_value);
     GraphWindow << reshow;
     Weibull_Window<<reshow;
     If( BETA_value == 1,
      NON_EXPO1,
      NON_EXPO2
     );
    )
   ),
   V List Box(
    H List Box( TB2=Text Box( " Scale Parameter Eta" ), Text Box("  ") ),
    Slider Box(
     0,
     10,
     Eta_value,
     TEXT_MESSAGE = "Shape parameter Beta = " || char(Beta_value) ||"; Scale parameter Eta = "  || char(Eta_value) || "; Location parameter Gamma = " || char(Gamma_value);
     GraphWindow << reshow;NON_EXPO2;
    )
   ),
   V List Box(
    H List Box( TB3=Text Box( " Location Parameter Gamma" ), Text Box("  ") ),
    Slider Box(
     0,
     10,
     Gamma_value,
     TEXT_MESSAGE = "Shape parameter Beta = " || char(Beta_value) ||"; Scale parameter Eta = "  || char(Eta_value) || "; Location parameter Gamma = " || char(Gamma_value);
     GraphWindow << reshow;NON_EXPO2;
    )
   )
  )
 
 )
);



TB1 << Font color( "BLUE" );
TB1 << set Font size( 10 );
TB2 << Font color( "BLUE" );
TB2 << set Font size( 10 );
TB3 << Font color( "BLUE" );
TB3 << set Font size( 10 );

---

---

Reliability and Reliability Engineering (Part 1)

From my previous entry 8 Dimensions of Quality I noted the Dr. David A. Garvin identified Reliability as one of the keys strategic objectives that quality practitioners can focus on. In this series I would discuss more the details of Reliability Management and Reliability Engineering. I will depend heavily on two great books, the “Quality Engineering Handbook” by Thomas Pyzdek (second edition, 2003 by Marcel Dekker, Inc), and of course “Juran’s Quality Handbook” by Joseph Juran and Blanton Godfrey (fifth edition, 1999 by McGraw-Hill). I will incorporate as well some examples on how to execute Reliability Analysis in JMP. I am using JMP 7.0.1 for this and will use its documentation as a reference.

Definition of Reliability

In the entry 8 Dimensions of Quality I differentiated quality and reliability by an analogy. If quality is a snapshot of the goodness of a product at a certain point in time, reliability is the consistency of that level of quality as time goes on. Thus, if quality is a photograph, reliability is a video. For a formal definition however, we will quote from Pyzdek’s book:
“…reliability is defined as the probability that a product or system will perform a specified function for a specified time without failure.”
In addition Pyzdek also cautions that for a reliability figure to be meaningful it has to be defined within the context of specific operating conditions. You do not expect a laptop to work in the same level of quality when it is submerged in water as when it is used in a room environment. For that exact reason, warranty is limited to a pre-defined correct way of using a product. In the same manner warranty claims are first examined if valid by comparing the condition in which it failed against the conditions stipulated in the warranty.

Key Measures of Reliability

The following is a list of the common measures of reliability.

• Mean Time to Fail (MTTF) or Mean Time to First Failure (MTFF) – This applies to products (or systems in general) that can not be repaired once it fails or break-down. When buying a light bulb for example, we assess how long it will take before it finally breaks down. The longer the time before it finally fails, the better we say that light bulb is.
• Mean Time between Failures (MTBF) – This applies to products (or systems in general) that breaks down but can be repaired and return to use. MTBF is defined as the average exposure a product will take until it will fail again. This exposure value may take a unit of time or count of usage. Within the context of the unit used, the higher the value of MTBF, the better the reliability is. Thus a machine that broke down 20 days after the repair is better than the one that took only half a day. In the same way, an oven that has to be re-calibrated by a thermocouple every 20 uses is much worse than an oven that needs only recalibration every after 500 uses. Both MTBF and MTTF can satisfactory be modelled by an Exponential distribution or by its generalized form, the Weibull distribution
• Failure Rate – This is the value of 1/MTBF. It is defined as the number of failures per unit of exposure. From the example above an MTBF of 20 days means failure rate of 1 machine per 20 days or 0.05 failures per day. Failure rate is important as it is often can be modelled by a Poisson distribution which facilitates ease of analysis.
• Mean Time to Repair (MTTR) – This measures the amount of time the product or tool or system in general is down. It is defined as the elapsed time between occurrence of failure and re-endorsement for use. Because of this definition MTTR is only applicable for repairable entities.
• Availability – This is defined as the proportion of time a product, or tool, or system in general is in a usable or operable state. Thus it is the ratio of time it is not under repair, to the total available time. Thus, Availability = MTBF/ (MTBF+MTTR).

The Life Cycle Model

Most failures of a product occurs either at the early stage (in cases there is an issue in the manufacturing process), or at the late stage where wear, tear, and degradation begins to take effect. This concept is called the System Life Cycle usually modelled by what is known as the Bathtub Curve. A typical Bathtub curve is shown below.



The Bathtub Curve above is produced by a Beta Distribution. In practice though, the infant stage is modelled by a Weibull distribution. That is, we can see the Bathtub Curve as an overlap of Weibull Distributions one of which is for the Infant Stage as shown below:

---

..to be continued